My Developer Memo

そろそろ64ビットOSも運用に乗りそうなくらいにこなれてきたようでそうなるとアプリケーションを開発する側としては、
時にプラットフォーム種別を判定する必要があることが出てくる。

32ビットか64ビットどちらのプラットフォームで動作しているかは IntPtr のサイズで分かるようである。

System.IntPtr.Size.ToString = 4 → 32ビット
System.IntPtr.Size.ToString = 8 → 64ビット

と判定できる。

しかし Webアプリケーションは64ビットでも32ビット（WOW64）環境でも動作させることができるので
さらにこれらの判定もする必要があるかもしれない。
ネットで探すと近いコードはあるのだがなかなか VB.NET のソースが無い！

ということでVB.NET化するとこんな感じでした。

Imports System.Runtime.InteropServices

''' <summary>
''' システム情報に関連するクラスです。
''' </summary>
''' <remarks></remarks>
Public Class SysInfoManager

#Region "# 変数・定数定義"

Enum BaseSystemInfo
        UNKNOWN = 0
        SYSINFO_32PROCESS = 1
        SYSINFO_32PROCESS_WO64 = 2
        SYSINFO_64PROCES = 3
    End Enum

Enum ArchitectureInfo
        PROCESSOR_ARCHITECTURE_INTEL = 0
        PROCESSOR_ARCHITECTURE_IA64 = 6
        PROCESSOR_ARCHITECTURE_AMD64 = 9
        PROCESSOR_ARCHITECTURE_UNKNOWN = 65535
    End Enum

<StructLayout(LayoutKind.Sequential)> _
    Private Structure SYSTEM_INFO
        Public wProcessorArchitecture As UShort
        Public wReserved As UShort
        Public dwPageSize As UInteger
        Public lpMinimumApplicationAddress As IntPtr
        Public lpMaximumApplicationAddress As IntPtr
        Public dwActiveProcessorMask As UIntPtr
        Public dwNumberOfProcessors As UInteger
        Public dwProcessorType As UInteger
        Public dwAllocationGranularity As UInteger
        Public wProcessorLevel As UShort
        Public wProcessorRevision As UShort
    End Structure

#End Region

#Region "# ＡＰＩ"

<DllImport("Kernel32.dll", SetLastError:=True, CharSet:=CharSet.Auto)> _
    Private Shared Function GetSystemWow64Directory(ByVal buffer As System.Text.StringBuilder, ByVal bufferSize As UInteger) As UInteger
    End Function

<DllImport("kernel32", SetLastError:=True)> _
    Private Shared Function GetCurrentProcess() As IntPtr
    End Function

<DllImport("kernel32", SetLastError:=True, CallingConvention:=CallingConvention.Winapi)> _
    Private Shared Function IsWow64Process(ByVal hProcess As IntPtr, _
                                           ByRef wow64Prcess As Boolean) As Boolean
    End Function
    <DllImport("kernel32", SetLastError:=True, CallingConvention:=CallingConvention.Winapi)> _
    Private Shared Function IsWow64Process(ByVal hProcess As Microsoft.Win32.SafeHandles.SafeHandleZeroOrMinusOneIsInvalid, _
                                           ByRef wow64Prcess As Boolean) As <MarshalAs(UnmanagedType.Bool)> Boolean
    End Function

<DllImport("kernel32", SetLastError:=True, CharSet:=CharSet.Auto, ExactSpelling:=False)> _
    Private Shared Function GetProcAddress(ByVal hModule As IntPtr, _
                                           <MarshalAs(UnmanagedType.LPStr)> ByVal lpProcName As String) As IntPtr
    End Function

<DllImport("kernel32", SetLastError:=True, CharSet:=CharSet.Auto)> _
    Private Shared Function GetModuleHandle(ByVal lpModuleName As String) As IntPtr
    End Function

<DllImport("kernel32.dll")> _
    Private Shared Sub GetNativeSystemInfo(ByRef lpSystemInfo As SYSTEM_INFO)
    End Sub

#End Region

''' <summary>
    ''' 64ビットオペレーティングシステムのWOW64上で動作しているかどうかを判定します。
    ''' </summary>
    ''' <returns>WOW64上で動作していればTrue、64ビットネイティブあるいは32ビットＯＳで動作していればFalseを返します。</returns>
    ''' <remarks></remarks>
    Private Shared Function IsWow64() As Boolean
        Dim bIsWow64 As Boolean = False
        Dim fnIsWow64Process As IntPtr

'IsWow64Process メソッドがあるかどうかを判定
        fnIsWow64Process = GetProcAddress(GetModuleHandle("kernel32"), "IsWow64Process")
        If (IntPtr.Zero <> fnIsWow64Process) Then
            If IsWow64Process(Process.GetCurrentProcess.Handle, bIsWow64) Then
                Return bIsWow64
                '64Any→False
                'WOW→True
                '32bit→False
            Else
                Return False
            End If
        Else
            '無いときは32ビットOS（でも32ビットOSでもTrueを返すが…）
            Return False
        End If
    End Function

''' <summary>
    ''' 実行中のオペレーティングシステムが64ビットＯＳかどうかを判定します。
    ''' </summary>
    ''' <returns></returns>
    ''' <remarks></remarks>
    Private Shared Function Is64Platform() As Boolean
        Dim fnGetNativeSystemInfo As IntPtr
        Dim info As New SYSTEM_INFO

fnGetNativeSystemInfo = GetProcAddress(GetModuleHandle("kernel32"), "GetNativeSystemInfo")
        If fnGetNativeSystemInfo <> IntPtr.Zero Then
            GetNativeSystemInfo(info)
            If info.wProcessorArchitecture = ArchitectureInfo.PROCESSOR_ARCHITECTURE_AMD64 Then      'Core2 64bit
                Return True
            ElseIf info.wProcessorArchitecture = ArchitectureInfo.PROCESSOR_ARCHITECTURE_IA64 Then
                Return True
            ElseIf info.wProcessorArchitecture = ArchitectureInfo.PROCESSOR_ARCHITECTURE_INTEL Then  'Intel 32bit
                Return False
            End If
        End If
    End Function

''' <summary>
    ''' 実行中のアプリケーションがどのシステムで動作しているかを取得します。
    ''' </summary>
    ''' <returns>
    ''' SYSINFO_32PROCESS     ：32ビットオペレーティングシステムで動作<br/>
    ''' SYSINFO_64PROCES      ：64ビットオペレーティングシステム上のネイティブ環境(64ビット)で動作<br/>
    ''' SYSINFO_32PROCESS_WO64：64ビットオペレーティングシステム上の32ビット環境(WOW64)で動作
    ''' </returns>
    ''' <remarks></remarks>
    Public Shared Function GetBaseSystemInfo() As BaseSystemInfo
        If (Is64Platform()) Then
            '64bitプラットフォーム
            If IsWow64() Then
                'WOW64上で動作する32bitアプリケーション
                Return BaseSystemInfo.SYSINFO_32PROCESS_WO64
            Else
                '64bitネイティブアプリケーション
                Return BaseSystemInfo.SYSINFO_64PROCES
            End If
        Else
            '32bitプラットフォーム
            Return BaseSystemInfo.SYSINFO_32PROCESS
        End If

End Function

End Class

開発に関する覚え書き

2008/09/26 (金)

●［CodeTips］64ビット判定

Comments

Comment form